From 607b426e269b17f4ad32dca9c612c4a9f8541766 Mon Sep 17 00:00:00 2001
From: Gammut
Date: Sun, 9 Jul 2023 11:35:32 -0500
Subject: Refactor queries for ecma based languages (#7207)

---
 runtime/queries/_javascript/highlights.scm | 36 ++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)
 create mode 100644 runtime/queries/_javascript/highlights.scm

(limited to 'runtime/queries/_javascript/highlights.scm')

diff --git a/runtime/queries/_javascript/highlights.scm b/runtime/queries/_javascript/highlights.scm
new file mode 100644
index 00000000..8b0bbb94
--- /dev/null
+++ b/runtime/queries/_javascript/highlights.scm
@@ -0,0 +1,36 @@
+; Function and method parameters
+;-------------------------------
+
+; Javascript and Typescript Treesitter grammars deviate when defining the
+; tree structure for parameters, so we need to address them in each specific
+; language instead of ecma.
+
+; (p)
+(formal_parameters 
+  (identifier) @variable.parameter)
+
+; (...p)
+(formal_parameters
+  (rest_pattern
+    (identifier) @variable.parameter))
+
+; ({ p })
+(formal_parameters
+  (object_pattern
+    (shorthand_property_identifier_pattern) @variable.parameter))
+
+; ({ a: p })
+(formal_parameters
+  (object_pattern
+    (pair_pattern
+      value: (identifier) @variable.parameter)))
+
+; ([ p ])
+(formal_parameters
+  (array_pattern
+    (identifier) @variable.parameter))
+
+; (p = 1)
+(formal_parameters
+  (assignment_pattern
+    left: (identifier) @variable.parameter))
-- 
cgit v1.2.3-70-g09d2