From 4b32b544fc57c53e1406fa7705068f0222498019 Mon Sep 17 00:00:00 2001
From: Clara Hobbs
Date: Thu, 6 Apr 2023 12:35:05 -0400
Subject: Add textobject queries for Julia (#6588)

* Add textobjects queries for Julia

* Update docs for Julia textobject queries---
 runtime/queries/julia/textobjects.scm | 46 +++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 runtime/queries/julia/textobjects.scm

(limited to 'runtime/queries/julia/textobjects.scm')

diff --git a/runtime/queries/julia/textobjects.scm b/runtime/queries/julia/textobjects.scm
new file mode 100644
index 00000000..1927c2b1
--- /dev/null
+++ b/runtime/queries/julia/textobjects.scm
@@ -0,0 +1,46 @@
+(function_definition (_)? @function.inside) @function.around
+
+(short_function_definition (_)? @function.inside) @function.around
+
+(macro_definition (_)? @function.inside) @function.around
+
+(struct_definition (_)? @class.inside) @class.around
+
+(abstract_definition (_)? @class.inside) @class.around
+
+(primitive_definition (_)? @class.inside) @class.around
+
+(parameter_list
+  ; Match all children of parameter_list *except* keyword_parameters
+  ([(identifier)
+    (slurp_parameter)
+    (optional_parameter)
+    (typed_parameter)
+    (tuple_expression)
+    (interpolation_expression)
+    (call_expression)]
+  @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(keyword_parameters
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(argument_list
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(type_parameter_list
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(line_comment) @comment.inside
+
+(line_comment)+ @comment.around
+
+(block_comment) @comment.inside
+
+(block_comment)+ @comment.around
+
+(_expression (macro_identifier
+    (identifier) @_name
+    (#match? @_name "^(test|test_throws|test_logs|inferred|test_deprecated|test_warn|test_nowarn|test_broken|test_skip)$")
+  )
+  .
+  (macro_argument_list) @test.inside) @test.around
-- 
cgit v1.2.3-70-g09d2