From e069fb9dea0d41eedb9257050f2231b7b0b88d0e Mon Sep 17 00:00:00 2001
From: Michael Davis
Date: Sat, 16 Oct 2021 03:58:04 -0500
Subject: Add highlight support for tree-sitter-query language (tsq) (#845)

* add submodule on tree-sitter/tree-sitter-tsq

mark tsq submodule as shallow

* add tree-sitter-tsq to languages

* add highlight queries for tsq

* Update .gitmodules

Co-authored-by: Blaž Hrastnik <blaz@mxxn.io>---
 runtime/queries/tsq/highlights.scm | 46 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 runtime/queries/tsq/highlights.scm

(limited to 'runtime/queries/tsq/highlights.scm')

diff --git a/runtime/queries/tsq/highlights.scm b/runtime/queries/tsq/highlights.scm
new file mode 100644
index 00000000..9ba5699a
--- /dev/null
+++ b/runtime/queries/tsq/highlights.scm
@@ -0,0 +1,46 @@
+; mark the string passed #match? as a regex
+(((predicate_name) @function
+  (capture)
+  (string) @string.regexp)
+ (#eq? @function "#match?"))
+
+; highlight inheritance comments
+((query . (comment) @keyword.directive)
+ (#match? @keyword.directive "^;\ +inherits *:"))
+
+[
+  "("
+  ")"
+  "["
+  "]"
+] @punctuation.bracket
+
+":" @punctuation.delimiter
+
+[
+  (one_or_more)
+  (zero_or_one)
+  (zero_or_more)
+] @operator
+
+[
+  (wildcard_node)
+  (anchor)
+] @constant.builtin
+
+[
+  (anonymous_leaf)
+  (string)
+] @string
+
+(comment) @comment
+
+(field_name) @property
+
+(capture) @label
+
+(predicate_name) @function
+
+(escape_sequence) @escape
+
+(node_name) @variable
-- 
cgit v1.2.3-70-g09d2