🧚 puck - an experimental programming language

A place where I can make some bad decisions.

Puck is an experimental, memory safe, structurally typed, interface-first, imperative programming language. It aims to be consistent and succinct while performant: inspired by the syntax and metaprogramming of Nim, the error handling of Swift, the memory management of Rust and Koka, the async/await and comptime of Zig, and the module system of OCaml.

# Note: These declarations are adapted from the standard prelude.

## The Result type. Represents either success or failure.
pub type Result[T, E] = union
  Okay(T)
  Error(E)

## The Err class. Useful for dynamically dispatching errors.
pub type Err = class
  str(Self): str
  dbg(Self): str

## A Result type that uses dynamically dispatched errors.
## The Error may be any type implementing the Err class.
pub type Result[T] = Result[T, ref Err]

## Implements the `dbg` function for strings.
## As the `str` function is already defined for strings,
## this in turn means strings now implicitly implement Err.
pub func dbg(self: str) = "\"" & self & "\""

# Note: These declarations are adapted from the standard prelude.

## Syntactic sugar for dynamic result type declarations.
pub macro !(T: type) =
  quote Result[`T`]

## Indirect access. Propagates `Error`.
pub macro ?[T, E](self: Result[T, E]) =
  quote
    match `self`
    of Okay(x) then x
    of Error(e) then return Error(e)

## Opens the std.tables module for unqualified use.
use std.tables

pub type Value = str
pub type Ident = str
pub type Expr = ref union # tagged, algebraic unions
  Literal(Value)
  Variable(Ident)
  Abstraction(param: Ident, body: Expr)
  Application(body: Expr, arg: Expr)
  Conditional(condition: Expr,
    then_branch: Expr, else_branch: Expr)

## Evaluate an Expr down to a Value, or return an Error.
pub func eval(context: mut Table[Ident, Value], expr: lent Expr): Value! =
  match expr # structural pattern matching and guards are supported but not shown
  of Literal(value) then
    Okay(value.clone) # ownership necessitates we explicitly clone
  of Variable(ident) then
    context.get(ident) # whitespace is significant but flexible
      .err("Could not find variable {} in context!"
      .fmt(ident)) # uniform function call syntax allows arbitrary piping/chaining
  of Application(body, arg) then
    if body of Abstraction(param, body as inner_body) then # compact matching with if
      context.set(param, context.clone.eval(arg)?)
      context.eval(inner_body) # all values must be handled: returns are implicit
    else
      Error("Expected Abstraction, found body {} and arg {}".fmt(body.clone, arg.clone))
  of Conditional(condition, then_branch, else_branch) then
    if context.clone.eval(condition)? == "true" then
      context.eval(then_case)
    else
      context.eval(else_case)
  of _ then Error("Invalid expression {}".fmt(expr))

# The top-level module declaration can be elided if the file shares the same name.
pub mod tables =
  ## The Table class. Any sort of table - no matter the underlying
  ## representation - must implement these methods.
  pub type Table[K, V] = class
    get(lent Self, lent K): lent V?
    get(mut Self, lent K): mut V?
    set(mut Self, lent K, V): V?
    pop(mut Self, lent K): V?
    clear(mut Self)
    size(lent Self): uint
    init(varargs (K, V)): Self

  ...

  pub mod hashtable =
    use std.hashes

    pub type HashTable[K, V] = struct
      ...

Why Puck?

Puck is primarily a testing ground and should not be used in any important capacity. Don't use it. Everything is unimplemented and it will break underneath your feet.

That said: in the future, once somewhat stabilized, reasons why you would use it would be for:

• The syntax, aiming to be flexible, predictable, and succinct, through the use of uniform function call syntax and significant whitespace
• The type system, being modern and powerful with a strong emphasis on safety, algebraic data types, optional and result types, first-class functions, generics, interfaces, and modules
• The memory management system, implementing a model of strict ownership with an optimized reference counting escape hatch
• The metaprogramming, providing integrated macros capable of rewriting the abstract syntax tree before or after typechecking
• The interop system, allowing foreign functions to be usable with native semantics from a bevy of languages

This is the language I keep in my head. It sprung from a series of unstructured notes I kept on language design, that finally became something more comprehensive in early 2023. The overarching goal is to provide a language capable of elegantly expressing any problem, and explore ownership and interop along the way.

How do I learn more?

• The basic usage document lays out the fundamental semantics of Puck.
• The syntax document provides a deeper and formal look into the grammar of Puck.
• The type system document gives an in-depth analysis of Puck's extensive type system.
• The modules document provides a more detailed look at the first-class module system.
• The memory management document gives an overview of Puck's memory model.
• The metaprogramming document explains how using metaprogramming to extend the language works.
• The asynchronous document gives an overview of Puck's colourless asynchronous support.
• The interop document gives an overview of how the first-class language interop system works.
• The standard library document provides an overview and examples of usage of the standard library.
• The roadmap provides a clear view of the current state and future plans of the language's development.

These are best read in order.

Note that all of these documents (and parts of this README) are written as if everything already exists. Nothing already exists! You can see the roadmap for an actual sense as to the state of the language. I simply found writing in the present tense to be an easier way to collect my thoughts.

This language does not currently integrate ideas from the following areas of active research: effects systems, refinement types, and dependent types. It plans to integrate refinement types in the future as a basis for range[] types, and to explore safety and optimizations surrounding integer overflow.

Primary References

• The Rust I wanted had no future
• Notes on a smaller Rust
• Notes on the next Rust compiler

An Overview of Puck

Puck is an experimental, high-level, memory-safe, statically-typed, whitespace-sensitive, interface-oriented, imperative programming language with functional underpinnings.

It attempts to explore designs in making functional programming paradigms comfortable to those familiar with imperative and object-oriented languages, as well as deal with some more technical problems along the way, such as integrated refinement types and typesafe interop.

This is the language I keep in my head. It reflects the way I think and reason about code.

I do hope others enjoy it.

Declarations and Comments

let ident: int = 413
# type annotations are optional
var phrase = "Hello, world!"
const compile_time = when linux then "linux" else "windows"

Variables may be mutable (var), immutable (let), or compile-time evaluated and immutable (const). Type annotations on variables and other bindings follow the name of the binding (with : Type), and are typically optional. Variables are conventionally written in snake_case. Types are conventionally written in PascalCase. The type system is comprehensive, and complex enough to warrant delaying full coverage of until the end. Some basic types are of note, however:

• int, uint: signed and unsigned integers
  • i[\d+], u[\d+]: arbitrary fixed-size counterparts
• float, decimal: floating-point numbers
  • f32/f64/f128: their fixed-size counterparts
  • dec64/dec128: their fixed-size counterparts
• byte: an alias to u8, representing one byte
• char: an alias to u32, representing one Unicode character
• bool: defined as union[false, true]
• array[T, size]: primitive fixed-size arrays
• list[T]: dynamic lists
• str: mutable strings. internally a list[byte], externally a list[char]
• slice[T]: borrowed "views" into the three types above

Comments are declared with # and run until the end of the line. Documentation comments are declared with ## and may be parsed by language servers and other tooling. Multi-line comments are declared with #[ ]# and may be nested. Taking cues from the Lisp family of languages, any expression may be commented out with a preceding #;.

Functions and Indentation

Functions are declared with the func keyword. They take an (optional) list of generic parameters (in brackets), an (optional) list of parameters (in parentheses), and must be annotated with a return type if they return a type. Every function parameter must be annotated with a type. Their type may optionally be prefixed with either lent, mut or const: denoting an immutable or mutable borrow (more on these later), or a constant type (known to the compiler at compile time, and usable in const exprs). Generic parameters may each be optionally annotated with a type functioning as a constraint.

Whitespace is significant but flexible: functions may be declared entirely on one line if so desired. A new level of indentation after certain tokens (=, do, then) denotes a new level of scope. There are some places where arbitrary indentation and line breaks are allowed - as a general rule of thumb, after operators, commas, and opening parentheses. The particular rules governing indentation may be found in the syntax guide.

Uniform Function Call Syntax

func inc(self: list[int], by: int): list[int] =
  self.map(x => x + by)

print inc([1, 2, 3], len("four")) # 5, 6, 7
print [1, 2, 3].inc(1)  # 2, 3, 4
print [1].len # 1

Puck supports uniform function call syntax: and so any function may be called using the typical syntax for method calls, that is, the first parameter of any function may be appended with a . and moved to precede it, in the style of a typical method. (There are no methods in Puck. All functions are statically dispatched. This may change in the future.)

This allows for a number of syntactic cleanups. Arbitrary functions with compatible types may be chained with no need for a special pipe operator. Object field access, module member access, and function calls are unified, reducing the need for getters and setters. Given a first type, IDEs using dot-autocomplete can fill in all the functions defined for that type. Programmers from object-oriented languages may find the lack of classes more bearable. UFCS is implemented in shockingly few languages, and so Puck joins the tiny club that previously consisted of just D and Nim.

Basic Types

Boolean logic and integer operations are standard and as one would expect out of a typed language: and, or, xor, not, shl, shr, +, -, *, /, <, >, <=, >=, div, mod, rem. Notably:

• the words and/or/not/shl/shr are used instead of the symbolic &&/||/!/<</>>
• integer division is expressed with the keyword div while floating point division uses /
• % is absent and replaced with distinct modulus and remainder operators
• boolean operators are bitwise and also apply to integers and floats
• more operators are available via the standard library (exp and log)

The above operations are performed with operators, special functions that take a prefixed first argument and (often) a suffixed second argument. Custom operators may be implemented, but they must consist of only a combination of the symbols = + - * / < > @ $ ~ & % | ! ? ^ \ for the purpose of keeping the grammar context-free. They are are declared identically to functions.

Term (in)equality is expressed with the == and != operators. Type equality is expressed with is. Subtyping relations may be queried with of, which has the additional property of introducing new bindings to the current scope in certain contexts (more on this in the types document).

let phrase: str = "I am a string! Wheeee! ✨"
for c in phrase do
  stdout.write(c) # I am a string! Wheeee! ✨
for b in phrase.bytes() do
  stdout.write(b.char) # Error: cannot convert from byte to char
print phrase.last() # ✨

String concatenation uses a distinct & operator rather than overloading the + operator (as the complement - has no natural meaning for strings). Strings are unified, mutable, internally a byte array, externally a char array, and are stored as a pointer to heap data after their length and capacity (fat pointer). Chars are four bytes and represent a Unicode character in UTF-8 encoding. Slices of strings are stored as a length followed by a pointer to string data, and have non-trivial interactions with the memory management system. More details can be found in the type system overview.

Conditionals and Pattern Matching

Basic conditional control flow uses standard if/elif/else statements. The when statement provides a compile-time if. It also takes elif and else branches and is syntactic sugar for an if statement within a const expression (more on those later).

All values in Puck must be handled, or explicitly discarded. This allows for conditional statements and many other control flow constructs to function as expressions: and evaluate to a value when an unbound value is left at the end of each of their branches' scopes. This is particularly relevant for functions, where it is often idiomatic to omit an explicit return statement. There is no attempt made to differentiate without context, and so expressions and statements often look identical in syntax.

Exhaustive structural pattern matching is available with the match/of statement, and is particularly useful for the struct and union types. of branches of a match statement take a pattern, of which the unbound identifiers within will be injected into the branch's scope. Multiple patterns may be used for one branch provided they all bind the same identifiers of the same type. Branches may be guarded with the where keyword, which takes a conditional, and will necessarily remove the branch from exhaustivity checks.

The of statement also stands on its own as an operator for querying subtype equality. Used as a conditional in if statements or while loops, it retains the variable injection properties of its match counterpart. This allows it to be used as a compact and coherent alternative to if let statements in other languages.

Error Handling

type Result[T] = Result[T, ref Err]
func may_fail: Result[T] = ...

Error handling is done via a fusion of functional monadic types and imperative exceptions, with much syntactic sugar. Functions may raise exceptions, but by convention should return Option[T] or Result[T, E] types instead: these may be handled in match or if/of statements. The compiler will track functions that raise errors, and warn on those that are not handled explicitly via try/with statements.

A bevy of helper functions and macros are available for Option/Result types, and are documented and available in the std.options and std.results modules (included in the prelude by default). Two in particular are of note: the ? macro accesses the inner value of a Result[T, E] or propagates (returns in context) the Error(e), and the ! accesses the inner value of an Option[T] / Result[T, E] or raises an error on None / the specific Error(e). Both operators take one parameter and so are postfix. The ? and ! macros are overloaded and additionally function on types as shorthand for Option[T] and Result[T] respectively.

The utility of the ? macro is readily apparent to anyone who has written code in Rust or Swift. The utility of the ! function is perhaps less so obvious. These errors raised by !, however, are known to the compiler: and they may be comprehensively caught by a single or sequence of catch statements. This allows for users used to a try/with error handling style to do so with ease, with only the need to add one additional character to a function call.

More details may be found in error handling overview.

Blocks and Loops

loop
  print "This will never normally exit."
  break

for i in 0 .. 3 do # exclusive
  for j in 0 ..= 3 do # inclusive
    print "{} {}".fmt(i, j)

Three types of loops are available: for loops, while loops, and infinite loops (loop loops). For loops take a binding (which may be structural, see pattern matching) and an iterable object and will loop until the iterable object is spent. While loops take a condition that is executed upon the beginning of each iteration to determine whether to keep looping. Infinite loops are infinite are infinite are infinite are infinite are infinite are infinite and must be manually broken out of.

There is no special concept of iterators: iterable objects are any object that implements the Iter[T] class (more on those in the type system document), that is, provides a self.next() function returning an Option[T]. As such, iterators are first-class constructs. For loops can be thought of as while loops that unwrap the result of the next() function and end iteration upon a None value. While loops, in turn, can be thought of as infinite loops with an explicit conditional break.

The break keyword immediately breaks out of the current loop, and the continue keyword immediately jumps to the next iteration of the current loop. Loops may be used in conjunction with blocks for more fine-grained control flow manipulation.

block
  statement

let x = block:
  let y = read_input()
  transform_input(y)

block foo
  for i in 0 ..= 100 do
    block bar
      if i == 10 then break foo
      print i

Blocks provide arbitrary scope manipulation. They may be labelled or unlabelled. The break keyword additionally functions inside of blocks and without any parameters will jump out of the current enclosing block (or loop). It may also take a block label as a parameter for fine-grained scope control.

Module System

Code is segmented into modules. Modules may be made explicit with the mod keyword followed by a name, but there is also an implicit module structure in every codebase that follows the structure and naming of the local filesystem. For compatibility with filesystems, and for consistency, module names are exclusively lowercase (following the same rules as Windows).

A module can be imported into another module by use of the use keyword, taking a path to a module or modules. Contrary to the majority of languages ex. Python, unqualified imports are encouraged - in fact, are idiomatic (and the default) - type-based disambiguation and official LSP support are intended to remove any ambiguity.

Within a module, functions, types, constants, and other modules may be exported for use by other modules with the pub keyword. All such identifiers are private by default and only accessible module-locally without. Modules are first-class and may be bound, inspected, modified, and returned. As such, imported modules may be re-exported for use by other modules by binding them to a public constant.

More details may be found in the modules document.

Compile-time Programming

Compile-time programming may be done via the previously-mentioned const keyword and when statements: or via const blocks. All code within a const block is evaluated at compile-time and all assignments and allocations made are propagated to the compiled binary as static data. Further compile-time programming may be done via macros: compile-time manipulation of the abstract syntax tree. The macro system is complex, and a description may be found in the metaprogramming document.

Async System and Threading

The async system is colourblind: the special async macro will turn any function call returning a T into an asynchronous call returning a Future[T]. The special await function will wait for any Future[T] and return a T (or an error). Async support is included in the standard library in std.async in order to allow for competing implementations. More details may be found in the async document.

Threading support is complex and also regulated to external libraries. OS-provided primitives will likely provide a spawn function, and there will be substantial restrictions for memory safety. I really haven't given much thought to this.

Memory Management

# Differences in Puck and Rust types in declarations and at call sights.
func foo(a:
  lent T → &'a T
  mut T → &'a mut T
  T → T
):
  lent T → &'a T
  mut T → &'a mut T
  T → T

let t: T = ...
foo( # this is usually elided
  lent t → &t
  mut t → &mut t
  t → t
)

Puck copies Rust-style ownership near verbatim. &T corresponds to lent T, &mut T to mut T, and T to T: with T implicitly convertible to lent T and mut T at call sites. A major goal of Puck is for all lifetimes to be inferred: there is no overt support for lifetime annotations, and it is likely code with strange lifetimes will be rejected before it can be inferred. (Total inference, however, is a goal.)

Another major difference is the consolidation of Box, Rc, Arc, Cell, RefCell into just two (magic) types: ref and refc. ref takes the role of Box, and refc both the role of Rc and Arc: while Cell and RefCell are disregarded. The underlying motivation for compiler-izing these types is to make deeper compiler optimizations accessible: particularly with refc, where the existing ownership framework is used to eliminate counts. Details on memory safety, references and pointers, and deep optimizations may be found in the memory management overview.

Types System

# The type Foo is defined here as an alias to a list of bytes.
type Foo = list[byte]

# implicit conversion to Foo in declarations
let foo: Foo = [1, 2, 3]

func fancy_dbg(self: Foo) =
  print "Foo:"
  # iteration is defined for list[byte]
  # so self is implicitly converted from Foo to list[byte]
  for elem in self do
    dbg(elem)

# NO implicit conversion to Foo on calls
[4, 5, 6].foo_dbg # this fails!

Foo([4, 5, 6]).foo_dbg # prints: Foo:\n 4\n\ 5\n 6\n

Finally, a few notes on the type system are in order. Types are declared with the type keyword and are aliases: all functions defined on a type carry over to its alias, though the opposite is not true. Functions defined on the alias must take an object known to be a type of that alias: exceptions are made for type declarations, but at call sites this means that conversion must be explicit.

# We do not want functions defined on list[byte] to carry over,
# as strings function differently (operating on chars).
# So we declare `str` as a struct, rather than a type alias.
pub type str = struct
  data: list[byte]

# However, the underlying `empty` function is still useful.
# So we expose it in a one-liner alias.
# In the future, a `with` macro may be available to ease carryover.
pub func empty(self: str): bool = self.data.empty

# Alternatively, if we want total transparent type aliasing, we can use constants.
pub const MyAlias: type = VeryLongExampleType

If one wishes to define a new type without previous methods accessible, the newtype paradigm is preferred: declaring a single-field struct, and manually implementing functions that carry over. It can also be useful to have transparent type aliases, that is, simply a shorter name to refer to an existing type. These do not require type conversion, implicit or explicit, and can be used freely and interchangeably with their alias. This is done with constants.

Types, like functions, can be generic: declared with "holes" that may be filled in with other types upon usage. A type must have all its holes filled before it can be constructed. The syntax for generics in types much resembles the syntax for generics in functions, and generic constraints and the like also apply.

Structs and Tuples

type MyStruct = struct
  a: str
  b: str
type MyTuple = (str, b: str)

let a: MyTuple = ("hello", "world")
print a.1 # world
print a.b # world

Struct and tuple types are declared with struct[<fields>] and tuple[<fields>], respectively. Their declarations make them look similar at a glance, but they differ fairly fundamentally. Structs are unordered, and every field must be named. They may be constructed with {} brackets. Tuples are ordered and so field names are optional - names are just syntactic sugar for positional access (foo.0, bar.1, ...). Tuples are constructed with () parentheses: and also may be declared with such, as syntactic sugar for tuple[...].

It is worth noting that there is no concept of pub at a field level on structs - a type is either fully transparent, or fully opaque. This is because such partial transparency breaks with structural initialization (how could one provide for hidden fields?). However, the @[opaque] attribute allows for expressing that the internal fields of a struct are not to be accessed or initialized: this, however, is only a compiler warning and can be totally suppressed with @[allow(opaque)].

Unions and Enums

type Expr = union
  Literal(int)
  Variable(str)
  Abstraction(param: str, body: ref Expr)
  Application(body: ref Expr, arg: ref Expr)

Union types are composed of a list of variants. Each variant has a tag and an inner type the union wraps over. Before the inner type can be accessed, the tag must be pattern matched upon, in order to handle all possible values. These are also known as sum types or tagged unions in other languages.

Union types are the bread and butter of structural pattern matching. Composed with structs and tuples, unions provide for a very general programming construct commonly referred to as an algebraic data type. This is often useful as an idiomatic and safer replacement for inheritance.

Enum types are similarly composed of a list of variants. These variants, however, are static values: assigned at compile-time, and represented under the hood by a single integer. They function similarly to unions, and can be passed through to functions and pattern matched upon, however their underlying simplicity and default values mean they are much more useful for collecting constants and acting as flags than anything else.

Classes

pub type Iter[T] = class
  next(mut Self): T?

pub type Peek[T] = class
  next(mut Self): T?
  peek(mut Self): T?
  peek_nth(mut Self, int): T?

Class types function much as type classes in Haskell or traits in Rust do. They are not concrete types, and cannot be constructed - instead, their utility is via indirection, as parameters in functions or as ref types in structures, providing constraints that some concrete type must meet. They consist of a list of function signatures, implementations of which must exist for the given type passed in in order to compile.

Their major difference, however, is that Puck's classes are implicit: there is no impl block that implementations of their associated functions have to go under. If functions for a concrete type exist satisfying some class, the type implements that class. This does run the risk of accidentally implementing a class one does not desire to, but the author believes such situations are few and far between and well worth the decreased syntactic and semantic complexity. As a result, however, classes are entirely unable to guarantee any invariants hold (like PartialOrd or Ord in Rust do).

As the compiler makes no such distinction between fields and single-argument functions on a type when determining identifier conflicts, classes similarly make no such distinction. They do distinguish borrowed/mutable/owned parameters, those being part of the type signature.

Classes are widely used throughout the standard library to provide general implementations of such conveniences like iteration, debug and display printing, generic error handling, and much more.

Syntax: A Casual and Formal Look

Call Syntax

There is little difference between a function, macro, and operator call. There are only a few forms such calls can take, too, though notably more than most other languages (due to, among other things, uniform function call syntax): hence this section.

# The standard, unambiguous call.
routine(1, 2, 3, 4)
# The method call syntax equivalent.
1.routine(2, 3, 4)
# A block-based call. This is only really useful for macros taking in a body.
routine
  1
  2
  3
  4
# A parentheses-less call. This is only really useful for `print` and `dbg`.
# Only valid at the start of a line.
routine 1, 2, 3, 4

Binary operators have some special rules.

# Valid call syntaxes for binary operators. What can constitute a binary
# operator is constrained for parsing's sake. Whitespace is optional.
1 + 2
1+2
+ 1, 2 # Only valid at the start of a line. Also, don't do this.
+(1, 2)

As do unary operators.

# The standard call for unary operators. Postfix.
1?
?(1)

Method call syntax has a number of advantages: notably that it can be chained: acting as a natural pipe operator. Redundant parenthesis can also be omitted.

# The following statements are equivalent:
foo.bar.baz
foo().bar().baz()
baz(bar(foo))
baz
  bar
    foo
baz bar(foo)
baz foo.bar

Indentation Rules

The tokens =, then, do, of, else, block, const, block X, and X (where X is an identifier) are scope tokens. They denote a new scope for their associated expressions (functions/macros/declarations, control flow, loops). The tokens ,, . (notably not ...), and all default binary operators (notably not not) are continuation tokens. An expression beginning or ending in one of them would always be a syntactic error.

Line breaks are treated as the end of a statement, with several exceptions.

pub func foo() =
  print "Hello, world!"
  print "This is from a function."

pub func inline_decl() = print "Hello, world!"

Indented lines following a line ending in a scope token are treated as belonging to a new scope. That is, indented lines following a line ending in a scope token form the body of the expression associated with the scope token.

Indentation is not obligatory after a scope token. However, this necessarily constrains the body of the associated expression to one line: no lines following will be treated as an extension of the body, only the expression associated with the original scope token. (This may change in the future.)

pub func foo(really_long_parameter: ReallyLongType,
another_really_long_parameter: AnotherReallyLongType) = # no indentation! this is ok
  print really_long_parameter # this line is indented relative to the first line
  print really_long_type

Lines following a line ending in a continuation token (and, additionally not and () are treated as a continuation of that line and can have any level of indentation (even negative). If they end in a scope token, however, the following lines must be indented relative to the indentation of the previous line.

let really_long_parameter: ReallyLongType = ...
let another_really_long_parameter: AnotherReallyLongType = ...

really_long_parameter
  .foo(another_really_long_parameter) # some indentation! this is ok

Lines beginning in a continuation token (and, additionally )), too, are treated as a continuation of the previous line and can have any level of indentation. If they end in a scope token, the following lines must be indented relative to the indentation of the previous line.

pub func foo() =
  print "Hello, world!"
pub func bar() = # this line is no longer in the above scope.
  print "Another function declaration."

Dedented lines not beginning or ending with a continuation token are treated as no longer in the previous scope, returning to the scope of the according indentation level.

if cond then this
else that

match cond
of this then ...
of that then ...

A line beginning with a scope token is treated as attached to the previous expression.

# Technically allowed. Please don't do this.
let foo
= ...

if cond then if cond then this
else that

for i
in iterable
do ...

match foo of this then ...
of that then ...

match foo of this
then ...
of that then ...

This can lead to some ugly possibilities for formatting that are best avoided.

# Much preferred.

let foo =
  ...
let foo = ...

if cond then
  if cond then
    this
else that
if cond then
  if cond then this
else that

for i in iterable do
  ...
for i in iterable do ...

match foo
of this then ...
of that then ...

The indentation rules are complex, but the effect is such that long statements can be broken almost anywhere.

Expression Rules

First, a word on the distinction between expressions and statements. Expressions return a value. Statements do not. That is all.

There are some syntactic constructs unambiguously recognizable as statements: all declarations, modules, and use statements. There are no syntactic constructs unambiguously recognizable as expressions. As calls returning void are treated as statements, and expressions that return a type could possibly return void, there is no explicit distinction between expressions and statements made in the parser: or anywhere before type-checking.

Expressions can go almost anywhere. Our indentation rules above allow for it.

# Some different formulations of valid expressions.

if cond then
  this
else
  that

if cond then this
else that

if cond
then this
else that

if cond then this else that

let foo =
  if cond then
    this
  else
    that

# Some different formulations of *invalid* expressions.
# These primarily break the rule that everything following a scope token
# (ex. `=`, `do`, `then`) not at the end of the line must be self-contained.

let foo = if cond then
    this
  else
    that

let foo = if cond then this
  else that

let foo = if cond then this
else that

# todo: how to handle this?
if cond then if cond then that
else that

# shrimple
if cond then
  if cond then that
else that

# this should be ok
if cond then this
else that

match foo of
this then ...
of that then ...

Reserved Keywords

The following keywords are reserved:

• variables: let var const
• control flow: if then elif else
• pattern matching: match of
• error handling: try with finally
• loops: while do for in
• blocks: loop block break continue return
• modules: pub mod use as
• functions: func varargs
• metaprogramming: macro quote when
• ownership: lent mut ref refc
• types: type struct tuple union enum class

The following keywords are not reserved, but liable to become so.

• impl object interface concept auto effect case
• suspend resume spawn pool thread closure static
• cyclic acyclic sink move destroy copy trace deepcopy

The following identifiers are in use by the standard prelude:

• logic: not and or xor shl shr div mod rem
• logic: + - * / < > <= >= == != is
• async: async await
• types: int uint float i\d+ u\d+
  • f32 f64 f128
  • dec64 dec128
• types: bool byte char str
• types: void never
• strings: & (string append)

The following punctuation is taken:

• = (assignment)
• . (chaining)
• , (parameters)
• ; (statements)
• : (types)
• # (comment)
• @ (attributes)
• _ (unused bindings)
• | (generics)
• \ (string/char escaping)
• () (parameters, tuples)
• [] (generics, lists)
• {} (scope, structs)
• "" (strings)
• '' (chars)
• `` (unquoting)
• unused on qwerty: ~ % ^ $
  • perhaps leave $ unused. but ~, %, and ^ totally could be...

A Formal Grammar

We now shall take a look at a more formal description of Puck's syntax.

Syntax rules are described in extended Backus–Naur form (EBNF): however, most rules surrounding whitespace, and scope, and line breaks, are modified to how they would appear after a lexing step.

Identifiers

Ident  ::= (Letter | '_') (Letter | Digit | '_')*
Letter ::= 'A'..'Z' | 'a'..'z' | '\x80'..'\xff' # todo
Digit  ::= '0'..'9'

Literals

Int ::= '-'? (DecLit | HexLit | OctLit | BinLit)
Float ::= '-'? DecLit '.' DecLit
BinLit ::= '0b' BinDigit ('_'? BinDigit)*
OctLit ::= '0o' OctDigit ('_'? OctDigit)*
HexLit ::= '0x' HexDigit ('_'? HexDigit)*
DecLit ::= Digit ('_'? Digit)*
BinDigit ::= '0'..'1'
OctDigit ::= '0'..'7'
HexDigit ::= Digit | 'A'..'F' | 'a'..'f'

Chars, Strings, and Comments

CHAR    ::= '\'' (PRINT - '\'' | '\\\'')* '\''
STRING  ::= SINGLE_LINE_STRING | MULTI_LINE_STRING
COMMENT ::= SINGLE_LINE_COMMENT | MULTI_LINE_COMMENT | EXPRESSION_COMMENT
SINGLE_LINE_STRING  ::= '"' (PRINT - '"' | '\\"')* '"'
MULTI_LINE_STRING   ::= '"""' (PRINT | '\n' | '\r')* '"""'
SINGLE_LINE_COMMENT ::= '#' PRINT*
MULTI_LINE_COMMENT  ::= '#[' (PRINT | '\n' | '\r' | MULTI_LINE_COMMENT)* ']#'
EXPRESSION_COMMENT  ::= '#;' SINGLE_STMT
PRINT ::= LETTER | DIGIT | OPR |
          '"' | '#' | "'" | '(' | ')' | # notably the dual of OPR
          ',' | ';' | '[' | ']' | '_' |
          '`' | '{' | '}' | ' ' | '\t'

Values

Value ::= Int | Float | String | Char | Array | Tuple | Struct
Array  ::= '[' (Expr (',' Expr)*)? ']'
Tuple  ::= '(' (Ident '=')? Expr (',' (Ident '=')? Expr)* ')'
Struct ::= '{' Ident '=' Expr (',' Ident '=' Expr)* '}'

Variables

Decl  ::= Let | Var | Const | Func | Type
Let   ::= 'let' Pattern (':' Type)? '=' Expr
Var   ::= 'var' Pattern (':' Type)? ('=' Expr)?
Const ::= 'pub'? 'const' Pattern (':' Type)? '=' Expr
Pattern ::= (Ident ('as' Ident)?) | Char | String | Number | Float |
            Ident? '(' Pattern (',' Pattern)* ')'

Declarations

Func  ::= 'pub'? 'func' Ident Generics? Parameters? (':' Type)? '=' Body
Macro ::= 'pub'? 'macro' Ident Generics? Parameters? (':' Type)? '=' Body
Generics   ::= '[' Ident (':' Type)? (',' Ident (':' Type)?)* ']'
Parameters ::= '(' Ident (':' Type)? (',' Ident (':' Type)?)* ')'

All arguments to functions must have a type. This is resolved at the semantic level, however. (Arguments to macros may lack types. This signifies a generic node.)

Types

TypeDecl ::= 'pub'? 'type' Ident Generics? '=' Type
Type     ::= TypeStruct | TypeTuple | TypeEnum | TypeUnion | SugarUnion |
             TypeClass | (Modifier* (Type | ('[' Type ']')))
TypeStruct ::= 'struct' ('[' Ident ':' Type (',' Ident ':' Type)* ']')?
TypeUnion  ::= 'union'  ('[' Ident ':' Type (',' Ident ':' Type)* ']')?
SugarUnion ::= '(' Ident ':' Type (',' Ident ':' Type)* ')'
TypeTuple  ::= 'tuple' ('[' (Ident ':')? Type (',' (Ident ':')? Type)* ']')?
TypeEnum   ::= 'enum'  ('[' Ident ('=' Expr)? (',' Ident ('=' Expr)?)* ']')?
TypeClass  ::= 'class' ('[' Signature (',' Signature)* ']')?
Modifier   ::= 'ref' | 'refc' | 'ptr' | 'lent' | 'mut' | 'const'
Signature  ::= Ident Generics? ('(' Type (',' Type)* ')')? (':' Type)?

Control Flow

If     ::= 'if' Expr 'then' Body ('elif' Expr 'then' Body)* ('else' Body)?
When   ::= 'when' Expr 'then' Body ('elif' Expr 'then' Body)* ('else' Body)?
Try    ::= 'try' Body
           ('except' Ident ('as' Ident)? (',' Ident ('as' Ident)?)*) 'then' Body)+
           ('finally' Body)?
Match  ::= 'match' Expr ('of' Pattern (',' Pattern)* ('where' Expr)? 'then' Body)+
While  ::= 'while' Expr 'do' Body
For    ::= 'for' Pattern 'in' Expr 'do' Body
Loop   ::= 'loop' Body
Block  ::= 'block' Ident? Body
Const  ::= 'const' Body
Quote  ::= 'quote' QuoteBody

Modules

Mod ::= 'pub'? 'mod' Ident '=' Body
Use ::= 'use' Ident ('.' Ident)* ('.' ('[' Ident (',' Ident)* ']'))?

Operators

Operator ::= 'and' | 'or' | 'not' | 'xor' | 'shl' | 'shr' |
             'div' | 'mod' | 'rem' | 'is' | 'in' | Opr+
Opr ::= '=' | '+' | '-' | '*' | '/' | '<' | '>' |
        '@' | '$' | '~' | '&' | '%' | '|' |
        '!' | '?' | '^' | '.' | ':' | '\\'

Calls and Expressions

This section is (quite) inaccurate due to complexities with respect to significant indentation. Heed caution.

Call ::= Ident ('[' Call (',' Call)* ']')? ('(' (Ident '=')? Call (',' (Ident '=')? Call)* ')')? |
         Ident Call (',' Call)* |
         Call Operator Call? |
         Call Body
Stmt ::= Let | Var | Const | Func | Type | Mod | Use | Expr
Expr ::= Block | Const | For | While | Loop | If | When | Try | Match | Call
Body ::= (Stmt ';')* Expr

References:

• Statements vs. Expressions
• Swift's Lexical Structure
• The Nim Programming Language
• Pietro's Notes on Compilers

Typing in Puck

! This section needs a rewrite. Proceed with low standards.

Puck has a comprehensive static type system, inspired by the likes of Nim, Rust, and Swift.

Basic types

Basic types can be one-of:

• bool: internally an enum.
• int: integer number. x bits of precision by default.
  • uint: same as int, but unsigned for more precision.
  • i[\d+], u[\d+]: arbitrarily sized integers
• float: floating-point number.
  • f32, f64: specified float sizes
• decimal: precision decimal number.
  • dec32, dec64, dec128: specified decimal sizes
• byte: an alias to u8.
• char: an alias to u32. For working with Unicode.
• str: a string type. mutable. packed: internally a byte-array, externally a char-array.
• void: an internal type designating the absence of a value. often elided.
• never: a type that denotes functions that do not return. distinct from returning nothing.

bool and int/uint/float and siblings (and subsequently byte and char) are all considered primitive types and are always copied (unless passed as mutable). More on when parameters are passed by value vs. passed by reference can be found in the memory management document.

Primitive types, alongside str, void, and never, form basic types. void and never will rarely be referenced by name: instead, the absence of a type typically implicitly denotes one or the other. Still, having a name is helpful in some situations.

integers

todo

strings

Strings are:

• mutable
• internally a byte array
• externally a char (four bytes) array
• prefixed with their length and capacity
• automatically resize

They are also quite complicated. Puck has full support for Unicode and wishes to be intuitive, performant, and safe, as all languages wish to be. Strings present a problem that much effort has been expended on in (primarily) Swift and Rust to solve.

Abstract Types

Abstract types, broadly speaking, are types described by their behavior rather than their implementation. They are more commonly know as abstract data types: which is confusingly similar to "algebraic data types", another term for the advanced types they are built out of under the hood. We refer to them here as "abstract types" to mitigate some confusion.

iterable types

Iterable types can be one-of:

• array[T, size]: Fixed-size arrays. Can only contain one type T. Of a fixed size size and cannot grow/shrink, but can mutate. Initialized in-place with [a, b, c].
• list[T]: Dynamic arrays. Can only contain one type T. May grow/shrink dynamically. Initialized in-place with [a, b, c]. (this is the same as arrays!)
• slice[T]: Slices. Used to represent a "view" into some sequence of elements of type T. Cannot be directly constructed: they are unsized. Cannot grow/shrink, but their elements may be accessed and mutated. As they are underlyingly a reference to an array or list, they must not outlive the data they reference: this is non-trivial, and so slices interact in complex ways with the memory management system.
• str: Strings. Described above. They are alternatively treated as either list[byte] or list[char], depending on who's asking. Initialized in-place with "abc".

These iterable types are commonly used, and bits and pieces of compiler magic are used here and there (mostly around initialization, and ownership) to ease use. All of these types are some sort of sequence: and implement the Iter interface, and so can be iterated (hence the name).

other abstract types

Unlike the iterable types above, these abstract types do not have a necessarily straightforward or best implementation, and so multiple implementations are provided in the standard library.

These abstract data types can be one-of:

• BitSet[T]: high-performance sets implemented as a bit array.
  • These have a maximum data size, at which point the compiler will suggest using a HashSet[T] instead.
• AssocTable[T, U]: simple symbol tables implemented as an association list.
  • These do not have a maximum size. However, at some point the compiler will suggest using a HashTable[T, U] instead.
• HashSet[T]: standard hash sets.
• HashTable[T, U]: standard hash tables.

These abstract types do not have a natural ordering, unlike the iterable types above, and thus do not implement Iter. Despite this: for utility an elems() iterator based on a normalization of the elements is provided for set and HashSet, and keys(), values(), and pairs() iterators are provided for table and HashTable (based on a normalization of the keys).

Parameter Types

Some types are only valid when being passed to a function, or in similar contexts. No variables may be assigned these types, nor may any function return them. These are monomorphized into more specific functions at compile-time if needed.

Parameter types can be one-of:

• mutable: func foo(a: mut str): Marks a parameter as mutable (parameters are immutable by default). Passed as a ref if not one already.
• constant: func foo(a: const str): Denotes a parameter whose value must be known at compile-time. Useful in macros, and with when for writing generic code.
• generic: func foo[T](a: list[T], b: T): The standard implementation of generics, where a parameter's exact type is not listed, and instead statically dispatched based on usage.
• constrained: func foo(a: str | int | float): A basic implementation of generics, where a parameter can be one-of several listed types. The only allowed operations on such parameters are those shared by each type. Makes for particularly straightforward monomorphization.
• functions: func foo(a: (int, int) -> int): First-class functions. All functions are first class - function declarations implicitly have this type, and may be bound in variable declarations. However, the function type is only terribly useful as a parameter type.
• slices: func foo(a: slice[...]): Slices of existing lists, strings, and arrays. Generic over length. These are references under the hood, may be either immutable or mutable (with mut), and interact non-trivially with Puck's ownership system.
• classes: func foo(a: Stack[int]): Implicit typeclasses. More in the classes section.
  • ex. for above: type Stack[T] = interface[push(mut Self, T); pop(mut Self): T]
• built-in interfaces: func foo(a: struct): Included, special interfaces for being generic over advanced types. These include struct, tuple, union, enum, interface, and others.

Several of these parameter types - specifically, slices, functions, and interfaces - share a common trait: they are not sized. The exact size of the type is not generally known until compilation - and in some cases, not even during compilation! As the size is not always rigorously known, problems arise when attempting to construct these parameter types or compose them with other types: and so this is disallowed. They may still be used with indirection, however - detailed in the section on reference types.

generic types

Functions can take a generic type, that is, be defined for a number of types at once:

# fully generic. monomorphizes based on usage.
func add[T](a: list[T], b: T) = a.push(b)

# constrained generics. restricts possible operations to the intersection
# of defined methods on each type.
func length[T](a: str | list[T]) =
  a.len # both strings and lists have a `len` method

# alternative formulation: place the constraint on a generic parameter.
# this ensures both a and b are of the *same* type.
func add[T: int | float](a: T, b: T) = a + b

The syntax for generics is func, ident, followed by the names of the generic parameters in brackets [T, U, V], followed by the function's parameters (which may then refer to the generic types). Generics are replaced with concrete types at compile time (monomorphization) based on their usage in function calls within the main function body.

Constrained generics have two syntaxes: the constraint can be defined directly on a parameter, leaving off the [T] box, or it may be defined within the box as [T: int | float] for easy reuse in the parameters.

Other constructions like type declarations themselves may also be generic over types. In the future, modules also may be generic: whether that is to be over types or over other modules is to be determined.

Reference Types

Types are typically constructed by value on the stack. That is, without any level of indirection: and so type declarations that recursively refer to one another, or involve unsized types (notably including parameter types), would not be allowed. However, Puck provides several avenues for indirection.

Reference types can be one-of:

• ref T: An owned reference to a type T. This is a pointer of size uint (native).
• refc T: A reference-counted reference to a type T. This allows escaping the borrow checker.
• ptr T: A manually-managed pointer to a type T. (very) unsafe. The compiler will yell at you.

type BinaryTree = ref struct
  left: BinaryTree
  right: BinaryTree

type AbstractTree[T] = class
  func left(self: Self): Option[AbstractTree[T]]
  func right(self: Self): Option[AbstractTree[T]]
  func data(self: Self): T

type AbstractRoot[T] = struct
  left: ref AbstractTree[T]
  right: ref AbstractTree[T]

# allowed, but unsafe & strongly discouraged
type UnsafeTree = struct
  left: ptr UnsafeTree
  right: ptr UnsafeTree

The ref prefix may be placed at the top level of type declarations, or inside on a field of a structural type. ref types may often be more efficient when dealing with large data structures. They also provide for the usage of unsized types (functions, interfaces, slices) within type declarations.

The compiler abstracts over ref types to provide optimization for reference counts: and so a distinction between Rc/Arc/Box is not needed. Furthermore, access implicitly dereferences (with address access available via .addr), and so a * dereference operator is also not needed.

Much care has been given to make references efficient and safe, and so ptr should be avoided if at all possible. They are only usable inside functions explicitly marked with #[safe].

The implementations of reference types are delved into in further detail in the memory management document.

Advanced Types

The type keyword is used to declare aliases to custom data types. These types are algebraic: they function by composition. Such algebraic data types can be one-of:

• struct: An unordered, named collection of types. May have default values.
• tuple: An ordered collection of types. Optionally named.
• enum: Ordinal labels, that may hold values. Their default values are their ordinality.
• union: Powerful matchable tagged unions a la Rust. Sum types.
• class: Implicit type classes. User-defined duck typing.

All functions defined on the original type carry over. If this is not desired, the newtype paradigm is preferred: declaring a single-field struct and copying function declarations over.

Types may be explicitly to and from via the Coerce and Convert classes and provided from and to functions.

structs

Structs are an unordered collection of named types.

They are declared with struct[identifier: Type, ...] and initialized with brackets: { field = "value", another = 500}. Structs are structural: while the type system is fundamentally nominal, and different type declarations are treated as distinct, a struct object initialized with {} is usable in any context that expects a struct with the same fields.

type LinkedNode[T] = ref struct
  previous: Option[LinkedNode[T]]
  next: Option[LinkedNode[T]]
  data: T

let node = { # inferred type: LinkedNode[int], from prints_data call
  previous = None, next = None
  data = 413
}

func pretty_print(node: LinkedNode[int]) =
  print node.data
  if node.next of Some(node) then
    node.pretty_print()

# structural typing!
prints_data(node)

tuples

Tuples are an ordered collection of either named and/or unnamed types.

They are declared with tuple[Type, identifier: Type, ...] and initialized with parentheses: (413, "hello", value: 40000). Syntactic sugar allows for them to be declared with () as well.

They are exclusively ordered - named types within tuples are just syntactic sugar for positional access. Passing a fully unnamed tuple into a context that expects a tuple with a named parameter is allowed (so long as the types line up).

let grouping = (1, 2, 3)

func foo: tuple[str, str] = ("hello", "world")
dbg grouping.foo # prints '("hello", "world")'

func bar(a: (str, str)) = a.1
dbg grouping.bar # prints '"world"'

Tuples are particularly useful for "on-the-fly" types. Creating type declarations to tuples is discouraged - structs are generally a better choice, as they are fully named, support default values, and may have their layout optimized by the compiler.

enums

Enums are ordinal labels that may have associated values.

They are declared with enum[Label, AnotherLabel = 4, ...] and are never initialized (their values are known statically). Enums may be accessed directly by their label, and are ordinal and iterable regardless of their associated value. They are useful in collecting large numbers of "magic values" that would otherwise be constants.

type Keys = enum
  Left, Right, Up, Down
  A = "a"
  B = "b"

In the case of an identifier conflict (with other enum labels, or types, or...) they must be prefixed with the name of their associated type (separated by a dot). This is standard for identifier conflicts: and is discussed in more detail in the modules document.

unions

Unions are tagged type unions. They provide a high-level wrapper over an inner type that must be safely accessed via pattern matching.

They are declared with union[Variant(Type), ...] and initialized with the name of a variant followed by its inner type constructor in brackets: Square(side: 5). Tuples and structs are special-cased to eliminate extraneous parentheses.

type Value = u64
type Ident = str
type Expr = ref union
  Literal(Value)
  Variable(Ident)
  Abstraction(param: Ident, body: Expr)
  Application(body: Expr, arg: Expr)
  Conditional(
    condition: Expr
    then_case: Expr
    else_case: Expr
  )

They take up as much space in memory as the largest variant, plus the size of the tag (one byte).

pattern matching

Unions abstract over differing types. In order to safely be used, their inner types must be accessed via pattern matching: leaving no room for type confusion. Pattern matching in Puck relies on two syntactic constructs: the match statement, forcing qualification and handling of all possible types of a variable, and the of statement, querying type equality while simultaneously binding new identifiers to underspecified portions of variables.

use std.tables

func eval(context: mut HashTable[Ident, Value], expr: Expr): Result[Value]
  match expr
  of Literal(value) then Okay(value)
  of Variable(ident) then
    context.get(ident).err("Variable not in context")
  of Application(body, arg) then
    if body of Abstraction(param, body as inner_body):
      context.set(param, context.eval(arg)?) # from std.tables
      context.eval(inner_body)
    else
      Error("Expected Abstraction, found {}".fmt(body))
  of Conditional(condition, then_case, else_case):
    if context.eval(condition)? == "true" then
      context.eval(then_case)
    else:
      context.eval(else_case)
  of expr then
    Error("Invalid expression {}".fmt(expr))

The match statement takes exclusively a list of of sub-expressions, and checks for exhaustivity. The expr of Type(binding) syntax can be reused as a conditional, in if statements and elsewhere.

The of operator is similar to the is operator in that it queries type equality, returning a boolean. However, unbound identifiers within of expressions are bound to appropriate values (if matched) and injected into the scope. This allows for succinct handling of union types in situations where match is overkill.

Each branch of a match expression can also have a guard: an arbitrary conditional that must be met in order for it to match. Guards are written as where cond and immediately follow the last pattern in an of branch, preceding then.

classes

Classes can be thought of as analogous to Rust's traits: without explicit impl blocks and without need for the derive macro. Types that have functions defined on them fulfilling the class requirements implicitly implement the associated class.

The class type is composed of a list of function signatures that refer to the special type Self that must exist for a type to be valid. The special type Self is replaced with the concrete type at compile time in order to typecheck. They are declared with class[signature, ...].

type Stack[T] = class
  push(self: mut Self, val: T)
  pop(self: mut Self): T
  peek(self: lent Self): lent T

func takes_any_stack(stack: Stack[int]) =
  # only stack.push, stack.pop, and stack.peek are available, regardless of the concrete type passed

Differing from Rust, Haskell, and many others, there is no explicit impl block. If there exist functions for a type that satisfy all of a class's signatures, it is considered to match and the class typechecks. This may seem strange and ambiguous - but again, static typing and uniform function call syntax help make this a more reasonable design. The purpose of explicit impl blocks in ex. Rust is three-fold: to provide a limited form of uniform function call syntax; to explicitly group together associated code; and to disambiguate. UFCS provides for the first, the module system provides for the second, and type-based disambiguation provides for the third, with such information exposed to the user via the language server protocol.

type Set[T] = class
  in(lent Self, T): bool
  add(mut Self, T)
  remove(mut Self, T): Option[T]

type Foo = struct
  a: int
  b: ref Set[int] # indirection: now perfectly valid

Classes cannot be constructed, as they are unsized. They serve purely as a list of valid operations on a type: no information about their memory layout is relevant. The concrete type fulfilling a class is known at compile time, however, and so there are no issues surrounding the use of classes as parameters, just when attempted to be used as (part of) a concrete type in ex. a struct. They can be used with indirection, however: as references are sized (consisting of a memory address).

## The Display class. Any type implementing `str` is printable.
## Any type that is Display must necessarily also implement Debug.
pub type Display = class
  str(Self): str
  dbg(Self): str

## The Debug class. Broadly implemented for every type with compiler magic.
## Types can (and should) override the generic implementations.
pub type Debug = class
  dbg(Self): str

Classes also cannot extend or rely upon other classes in any way, nor is there any concept of a parameter satisfying two classes. In the author's experience, while such constructions are powerful, they are also an immense source of complexity, leading to less-than-useful hierarchies seen in languages like Java, and yes, Rust. Instead, if one wishes to form an class that also satisfies another class, they must name a new class that explicitly includes all of the other class's associated functions. Given that classes in Puck overwhelmingly only have a small handful of associated functions, and if you're using more than one class you really should be using a concrete type: the hope is that this will provide for explicitness and reduce complexity.

Classes compose well with modules to offer fine grained access control.

Errata

default values

Puck does not have any concept of null: all values must be initialized. But always explicitly initializing types is syntactically verbose, and so most types have an associated "default value".

Default values:

• bool: false
• int, uint, etc: 0
• float, etc: 0.0
• char: '\0'
• str: ""
• void, never: unconstructable
• array[T], list[T]: []
• set[T], table[T, U]: {}
• tuple[T, U, ...]: (default values of its fields)
• struct[T, U, ...]: {default values of its fields}
• enum[One, Two, ...]: disallowed
• union[T, U, ...]: disallowed
• slice[T], func: disallowed
• ref, refc, ptr: disallowed

For unions, slices, references, and pointers, this is a bit trickier. They all have no reasonable "default" for these types aside from null. Instead of giving in, the compiler instead disallows any non-initializations or other cases in which a default value would be inserted.

todo: consider user-defined defaults (ex. structs)

signatures and overloading

Puck supports overloading - that is, there may exist multiple functions, or multiple types, or multiple modules, with the same name - so long as they have a different signature. The signature of a function/type/module is important. Classes, among other constructs, depend on the user having some understanding of what the compiler considers to be a signature. So we state it here explicitly:

• The signature of a function is its name and the types of each of its parameters, in order, ignoring optional parameters. Generic parameters are ???
  • ex. ...
• The signature of a type is its name and the number of generic parameters.
  • ex. both Result[T] and Result[T, E] are defined in std.results
• The signature of a module is just its name. This may change in the future.

structural subtyping

Mention of subtyping has been on occasion in contexts surrounding structural type systems, particularly the section on distinct types, but no explicit description of what the subtyping rules are have been given.

Modules and Namespacing

! This section is incomplete. Proceed with caution.

Puck has a first-class module system, inspired by such expressive designs in the ML family.

What are modules?

pub mod stack =
  pub type Stack[T] = class
    init(static type Self): Stack[T]
    push(mut Self, val: T)
    pop(mut Self): T?
    peek(lent Self): lent T?

  pub mod list =
    type ListStack[T] = list[T]

    pub func init[T](self: static type ListStack[T]): Stack[T] = []
    pub func push[T](self: mut ListStack[T], val: T) = self.push(T)
    pub func pop[T](self: mut ListStack[T]): T? = self.pop
    pub func peek[T](self: lent ListStack[T]): lent T? =
      if self.len == 0 then None else Some(self.last)

use stack.list

let a = ListStack[int].init
print a.len # error: unable to access method on private type outside its module

a.push(5)
print a.pop # Some(5)

Modules package up code for use by others. Identifiers known at compile time may be part of a module: these being constants, functions, macros, types, and other modules themselves. Such identifiers may be made accessible outside of the module by prefixing them with the pub keyword.

Importantly, files are implicitly modules, public and named with their filename. The mod keyword followed by an identifier and an indented block of code explicitly defines a module, inside of the current module. Modules are first class: they may be bound to constants (having the type : mod) and publicly exported, or bound to local variables and passed into functions for who knows what purpose.

Using modules

The use keyword lets you use other modules.

The use keyword imports public symbols from the specified module into the current scope unqualified. This runs contrary to expectations coming from most other languages: from Python to Standard ML, the standard notion of an "import" puts the imported symbols behind another symbol to avoid "polluting the namespace". As Puck is strongly typed and allows overloading, however, we see no reason for namespace pollution to be of concern. These unqualified imports have the added benefit of making uniform function call syntax more widely accessible. It is inevitable that identifier conflicts will exist on occasion, of course: when this happens, the compiler will force qualification (this then does restrict uniform function call syntax). We discuss this more later.

Nonetheless, if qualification of imports is so desired, an alternative approach is available - binding a module to a constant. Both the standard library and external libraries are available behind identifiers without use of use: std and lib, respectively. (FFI and local modules will likely use more identifiers, but this is not hammered out yet.) A submodule - for example, std.net - may be bound in a constant as const net = std.net, providing all of the modules' public identifiers for use, as fields of the constant net. We will see this construction to be extraordinarily helpful in crafting high-level public APIs for libraries later on.

use std.[logs, test]
use lib.crypto, lib.http

Multiple modules can be imported at once. The standard namespaces deserve more than a passing mention. There are several of these: std for the standard library, lib for all external libraries, pkg for the top-level namespace of a project, this for the current containing module... In addition: there are a suite of language namespaces, for FFI - rust, nim, and swift preliminarily - that give access to libraries from other languages. Recall that imports are unqualified - so use std will allow use of the standard library without the std qualifier (not recommended: several modules have common names), and use lib will dump the name of every library it can find into the global namespace (even less recommended).

Implicit Modules

A major goal of Puck's module system is to allow the same level of expressiveness as the ML family, while cutting down on the extraneous syntax and boilerplate needed to do so. As such, access modifiers are written directly inline with their declaration, and the file system structure is reused to form an implicit module system for internal use. This - particularly the former - limits the structure a module can expose at first glance, but we will see later that classes recoup much of this lost specificity.

We mentioned that the filesystem forms an implicit module structure. This begets a couple of design choices. Module names must be lowercase, for compatibility with case-insensitive filesystems. Both a file and a folder with the same name can exist. Files within the aforementioned folder are treated as submodules of the aforementioned file. This again restricts the sorts of module structures we can build, but we will see later that this restriction can be bypassed.

The this and pkg modules are useful for this implicit structure...

Defining interfaces

...

Defining an external API

The filesystem provides an implicit module structure, but it may not be the one you want to expose to users.

...

Error Handling

Puck's error handling is heavily inspired syntactically by Swift and semantically by the underlying effects system. It uses a combination of monadic error handling and effectful error propagation, with much in the way of syntactic sugar for conversion between the two, and leans somewhat heavily on Puck's metaprogramming capabilities. In comparison to Rust, it is considerably more dynamic by default.

There are several ways to handle errors in Puck. If the error is encoded in the type (as an Option or Result type), one can:

1. match on the error
2. compactly match on the error with if ... of
3. propagate the error with ?
4. throw the error with !

If the error is thrown (encoded as an effect), one can:

1. ignore the error, propagating it up the call stack
2. recover from the error in a try block
3. convert the error to a Result[T] (monadic form)

If an error is thrown, one must explicitly handle it at some level of the stack, or risk runtime failure. This method of error handling may feel more familiar to Java programmers. The compiler will warn on - but not enforce catching - such unhandled errors.

Errors as monads

Puck provides Option[T] and a Result[T, E] types, imported by default. These are union types under the hood and so must be pattern matched upon to be useful: but the standard library provides a bevy of helper functions. Two in particular are of note. The ? operator unwraps a Result or propagates its error up a function call (and may only be used in type-appropriate contexts). The ! operator unwraps an Option or Result directly or throws an exception in the case of None or Error.

pub macro ?[T, E](self: Result[T, E]) =
  quote
    match `self`
    of Okay(x) then x
    of Error(e) then return Error(e)

pub func ![T](self: Option[T]): T =
  match self
  of Some(x) then x
  of None then raise "empty value"

pub func ![T, E](self: Result[T, E]): T =
  match self
  of Okay(x) then x
  of Error(e) then raise e

The utility of the provided helpers in std.options and std.results should not be understated. While encoding errors into the type system may appear restrictive at first glance, some syntactic sugar goes a long way in writing compact and idiomatic code. Java programmers in particular are urged to give type-first errors a try, before falling back on unwraps and try/with.

A notable helpful type is the aliasing of Result[T] to Result[T, ref Err], for when the particular error does not matter. This breaks match exhaustion (as ref Err denotes a reference to any Error), but is particularly useful when used in conjunction with the propagation operator.

Errors as checked exceptions

Some functions do not return a value but can still fail: for example, setters. This can make it difficult to do monadic error handling elegantly. One could return a type Success[E] = Result[void, E], but such an approach is somewhat inelegant. Instead: we treat an assert within a function as having an effect: a possible failure, that can be handled and recovered from at any point in the call stack. If a possible exception is not handled within a function body, the function is implicitly marked by the compiler as throwing that exception.

pub type list[T] = struct
  data: ptr T
  capacity: uint
  length: uint

@[safe]
pub func set[T](self: list[T], i: uint, val: T) =
  if i > self.length then
    raise IndexOutOfBounds
  self.data.set(offset = i, val)

var foo = ["Hello", "world"]
foo.set(0, "Goodbye") # set can panic
# this propagates an IndexOutOfBounds effect up the call stack.

Despite functioning here as exceptions: errors remain types. An error thrown from an unwrapped Result[T, E] is of type E. with statements, then, may pattern match upon possible errors, behaving semantically and syntactically similarly to of branches: though notably not requiring exhaustion.

try
  foo.set(0, "Goodbye")
with IndexOutOfBounds(index) then
  dbg "Index out of bounds at {}".fmt(index)
  panic
finally
  ...

This creates a distinction between two types of error handling, working in sync: functional error handling with Option and Result types, and object-oriented error handling with algebraic effects. These styles may be swapped between with minimal syntactic overhead. It is up to libraries to determine which classes of errors are exceptional and best given the effect treatment and which should be explicitly handled monadically. Libraries should tend towards using Option/Result as this provides the best support for both styles (thanks to the ! operator).

Unrecoverable exceptions

There exist errors from which a program can not reasonably recover. These are the following:

• Assertation Failure: a call to an unhandled assert function has returned false at runtime.
• Out of Memory: the executable is out of memory.
• Stack Overflow: the executable has overflowed the stack.
• any others?

They are not recoverable, and not handled within the effects system, but the user should be aware of them as possible failure conditions.

References

• Error Handling in Swift
• Algebraic Effects for the rest of us

Asynchronous Programming

! This section is a draft. Many important details have yet to be ironed out.

Puck has colourless async/await, heavily inspired by Zig's implementation.

pub func fetch(url: str): str = ...

let a: Future[T] = async fetch_html()
let b: T = a.await
let c: T = await async fetch_html()

Puck's async implementation relies heavily on its metaprogramming system.

The async macro will wrap a call returning T in a Future[T] and compute it asynchronously. The await function takes in a Future[T] and will block until it returns a value (or error). The Future[T] type is opaque, containing internal information useful for the async and await routines.

pub macro async(self): Future[T] =
  ... todo ...

pub func await[T](self: Future[T]): T =
  while not self.ready do
    # block
  self.value! # apply callbacks?

This implementation differs from standard async/await implementations quite a bit. In particular, this means there is no concept of an "async function" - any block of computation that resolves to a value can be made asynchronous. This allows for "anonymous" async functions, among other things.

This (packaging up blocks of code to suspend and resume arbitrarily) is hard, and requires particular portable intermediate structures out of the compiler. Luckily, Zig is doing all of the R&D here. Some design decisions to consider revolve around APIs. The Linux kernel interface (among other things) provides both synchronous and asynchronous versions of its API, and fast code will use one or the other, depending if it is in an async context. Zig works around this by way of a known global constant that low-level functions read at compile time to determine whether to operate on synchronous APIs or asynchronous APIs. This is... not great. But what's better?

Threading

It should be noted that async is not the same as threading, nor is it solely useful in the presence of threads...

How threads work deserves somewhat of a mention...

References:

• What color is your function?
• What is Zig's "colorblind" async/await?
• Zig Learn: Async
• Rust async is colored and that's not a big deal
• Why is there no need for async/await in Elixir?
• Async/await on Wikipedia
• nim-chronos
• nim-cps
• tokio
• Zig-style async/await for Nim

Is async worth having separate from effect handlers? I think so...

Metaprogramming

Puck has rich metaprogramming support, heavily inspired by Nim. Many features that would have to be at the compiler level in most languages (error propagation ?, std.fmt.print, ?, !, -> type sugar, => closure sugar, async/await) are instead implemented as macros within the standard library.

Macros take in fragments of the AST within their scope, transform them with arbitrary compile-time code, and spit back out transformed AST fragments to be injected and checked for validity. This is similar to what the Lisp family of languages do. It has a number of benefits: there is no separate metaprogramming language, it is syntactically and semantically hygienic, and the underlying framework can be reused for all kinds of compile-time code execution.

By keeping an intentionally minimal AST, some things not possible to express in literal code may be expressible in the AST: in particular, bindings can be injected in many places they could not be injected in ordinarily. (A minimal AST also has the benefit of being quite predictable.)

Macros may not change Puck's syntax: the syntax is flexible enough. They have the same scope as other routines, that is:

function scope: takes the arguments within or following a function call

macro print(params: varargs) =
  var res = Call("write", [stdout])
  for param in params do
    res.params.add(param)

print(1, 2, 3, 4)
print "hello", " ", "world", "!"

block scope: takes the expression following a colon as a single argument

macro my_macro(body)

my_macro
  1
  2
  3
  4

operator scope: takes one or two parameters either as an infix (two parameters) or a postfix (one parameter) operator

# operators are restricted to punctuation
macro +=(a, b) =
  Call("=", [a, Call("+", [a, b])])

a += b

Macros typically take a list of parameters without types, but they optionally may be given a type to constrain the usage of a macro. Regardless: as macros operate at compile time, their parameters are not instances of a type, but rather an Expr expression representing a portion of the abstract syntax tree. Similarly, macros always return an Expr to be injected into the abstract syntax tree despite the usual absence of an explicit return type, but the return type may be specified to additionally typecheck the returned Expr.

As macros operate at compile time, they may not inspect the values that their parameters evaluate to. However, parameters may be marked const: in which case they will be treated like parameters in functions: as values. (note constant parameters may be written as const[T] or const T.)

macro ?[T, E](self: Result[T, E]) =
  quote
    match `self`
    of Okay(x) then x
    of Error(e) then return Error(e)

func meow: Result[bool, ref Err] =
  let a = stdin.get()?

The quote macro is special. It takes in literal code and returns that code as the AST. Within quoted data, backticks may be used to break out in order to evaluate and inject arbitrary code: though the code must evaluate to an expression of type Expr. Thus, quoting is structured: one cannot simply quote any arbitrary section. Quoting is very powerful: most macros are implemented using it.

The Expr type is available from std.ast, as are many helpers, and combined they provide the construction of arbitrary syntax trees (indeed, quote relies on and emits types of it). It is a union type with its variants directly corresponding to the variants of the internal AST of Puck.

Construction of macros can be difficult: and so several helpers are provided to ease debugging. The Debug and Display interfaces are implemented for abstract syntax trees: dbg will print a representation of the passed syntax tree as an object, and print will print a best-effort representation as literal code. Together with quote and optionally with const, these can be used to quickly get the representation of arbitrary code.

Interop with Other Languages

! This section is a draft. Many important details have yet to be ironed out.

A major goal of Puck is minimal-overhead language interoperability while maintaining type safety.

The problems of interop

There are three issues that complicate language interop:

1. The language of communication, i.e. the C ABI.
2. Conflicting type systems, i.e. Python vs. Rust
3. Conflicting memory management systems, i.e. tracing / reference counting vs. ownership

For the first, Puck is being written at the same time as the crABI ABI spec is in development. crABI promises a C-ABI-compatible, cross-language ABI spec: which would dramatically simplify the task of linking to object files produced by other languages (so long as languages actually conform to the ABI). It is being led by the Rust language team, and both Nim and Swift developers have expressed interest in it, which bodes quite well for its future.

For the second, Puck has a type system of similar capability to that of Rust, Nim, and Swift: and thus interop with those languages should be a straightforward exchange of types. Its type system is strictly more powerful than that of Python or C, and so interop requires additional help. Its type system is equally as powerful as but somewhat orthogonal to Java's, and so interop will be a little more difficult.

For the third: Puck uses what amounts to a combination of ownership and reference counting: and thus it is exchangeable in this regard with Rust. Nim and Swift, by contrast, use reference counting: which is not directly compatible with ownership, as attempting to use an owned type as a GC'd reference will immediately lead to a use-after-free. Puck may have to explore some form of gradual typing at linking-time to accommodate making its functions available for use. Using functions from GC'd languages, however, is perfectly doable with the refc type: though this may necessitate copying object graphs over the call boundary.

There is additional significant work being put into the use of Wasm as a language runtime. Wasm allows for - among other things - the sharing of garbage collectors, which means that any garbage-collected language compiling to it can simply use the primitive refc type to denote a garbage-collected reference. This does not, however, immediately work off the bat with ownership: as ownership necessitates certain invariants that garbage collection does not preserve. There is active research into fixing this: notably RichWasm, which retrofits a structural type system with ownership atop Wasm. Such extensions necessitate the runtime environment to implement them, however, and so Puck may have to explore some form of gradual typing for the broader Wasm ecosystem.

Usability

use std.io
use rust.os.linux
use nim.os.sleep
...

Languages often focus on interop from purely technical details. This is very important: but typically little thought is given to usability (and often none can be, for necessity of compiler support), and so using foreign function interfaces very much feel like using foreign function interfaces. Puck attempts to change that.

@[form(this-function)]
pub func this_function() = ...

A trivial concern is that identifiers are not always the same across languages: for example, in Racket this-function is a valid identifier, while in Puck the - character is disallowed outright. Matters of convention are issues, too: in Puck, snake_case is preferred for functions and PamelCase for types, but this is certainly not always the case. Puck addresses this at an individual level by attributes allowing for rewriting: and at a language level by consistent rewrite rules.

...todo...

Existing systems to learn from:

• The Rust ABI
• rust-interop
• CBindGen
• swift-bridge
• Kotlin C interop
• rust-lang-interop
• extern in Rust
• NimPy
• JNim
• Futhark
• Haxe's callfunc