Add textobject for javascript (#3213)

1 files changed, 36 insertions, 0 deletions

diff --git a/runtime/queries/javascript/textobjects.scm b/runtime/queries/javascript/textobjects.scm
new file mode 100644
index 00000000..c80dc81b
--- /dev/null
+++ b/runtime/queries/javascript/textobjects.scm
@@ -0,0 +1,36 @@
+(function_declaration
+  body: (_) @function.inside) @function.around
+
+(function
+  body: (_) @function.inside) @function.around
+
+(arrow_function
+  body: (_) @function.inside) @function.around
+
+(method_definition
+  body: (_) @function.inside) @function.around
+
+(generator_function_declaration
+  body: (_) @function.inside) @function.around
+
+(class_declaration
+  body: (class_body) @class.inside) @class.around
+
+(class
+  (class_body) @class.inside) @class.around
+
+(export_statement
+  declaration: [
+    (function_declaration) @function.around
+    (class_declaration) @class.around 
+  ])
+
+(formal_parameters
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(arguments
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(comment) @comment.inside
+
+(comment)+ @comment.around